module(
    name = "llvm",
    version = "0.6.9",
    bazel_compatibility = [">=8.3.0"],
    compatibility_level = 0,
)

bazel_dep(name = "bazel_lib", version = "3.2.2")
bazel_dep(name = "bazel_skylib", version = "1.8.2")
bazel_dep(name = "bazel_features", version = "1.42.0")
bazel_dep(name = "platforms", version = "1.0.0")
bazel_dep(name = "rules_cc", version = "0.2.16")
bazel_dep(name = "rules_shell", version = "0.6.1")
bazel_dep(name = "rules_python", version = "1.7.0")
bazel_dep(name = "with_cfg.bzl", version = "0.12.0")
bazel_dep(name = "tar.bzl", version = "0.9.0")

http_archive = use_repo_rule("@bazel_tools//tools/build_defs/repo:http.bzl", "http_archive")

rbe_platform_repository = use_repo_rule("//:rbe.bzl", "rbe_platform_repository")

rbe_platform_repository(
    name = "rbe_platform",
)

LLVM_VERSION = "22.1.0"

PREBUILT_LLVM_SUFFIX = "-3"

LLVM_TOOLCHAIN_MINIMAL_SHA256 = {
    "darwin-amd64": "88c39005ab8c141b4bc2c66c3a945d02214be0171db952cc4dc2efe15fc032bf",
    "darwin-arm64": "258cda3bf8ae6dd72c80ef50462da0470006a057769ab828f937932dd5451779",
    "linux-amd64-musl": "e5acf3dcab4dc7e538cfc590e11fde540153b89c465852110be3673f71c618f5",
    "linux-arm64-musl": "42b5a25dd48cadd619c248ef759640fa697f384785983b98c2c36c0179f96a2c",
    "windows-amd64": "46bc45ab18ff51714e83895382d1a2f76823f887d74c1435865fea473d45cb84",
    "windows-arm64": "52111b117a7c1019012bb1c64ffae57b4ec0a84f580338a3b93a33204010a958",
}

[
    http_archive(
        name = "llvm-toolchain-minimal-{llvm_version}-{target}".format(
            llvm_version = LLVM_VERSION,
            target = target.replace("-musl", ""),
        ),
        build_file = "//toolchain/llvm:llvm_release.BUILD.bazel" if "windows" not in target else "//toolchain/llvm:llvm_release_windows.BUILD.bazel",
        sha256 = sha256,
        urls = ["https://github.com/cerisier/toolchains_llvm_bootstrapped/releases/download/llvm-{llvm_version}{prebuilt_llvm_suffix}/llvm-toolchain-minimal-{llvm_version}-{target}.tar.zst".format(
            llvm_version = LLVM_VERSION,
            prebuilt_llvm_suffix = PREBUILT_LLVM_SUFFIX,
            target = target,
        )],
    )
    for (target, sha256) in LLVM_TOOLCHAIN_MINIMAL_SHA256.items()
]

TOOLCHAIN_EXTRAS_SHA256 = {
    "darwin-amd64": "8ca592e4fa4fb834f19b7b888dfc17b333636eb8bc17a5acca9ef222aa76f02c",
    "darwin-arm64": "fb27e74ad1dfa381bd066ebb9f07e19f8a0b4a35233a24967696ae2956c6ba6f",
    "linux-amd64-musl": "ce21e4697c37a6e0cd8e13c195c6d7f6f1efe7c4a4664128253c26bcb970fadc",
    "linux-arm64-musl": "2e229e13cd25e45e7f810c36384b17d8376826a26c6c90f13dd5dc04988a398f",
    "windows-amd64-gnu": "0a660dc8039a585a32cbe60edec56c195f357b7b01299f11a9a613046aca19bb",
    "windows-arm64-gnu": "9fe79b08e9ec308584f1f83455a77f0e3451b8b009c093a070eaa633304c0f1a",
}

TOOLCHAIN_EXTRAS_VERSION = "20260307"

[
    http_archive(
        name = "toolchain-extra-prebuilts-{target}".format(target = target.replace("-musl", "").replace("-gnu", "")),
        build_file = "//prebuilt/extras:extras.BUILD.bazel",
        sha256 = sha256,
        urls = ["https://github.com/cerisier/toolchains_llvm_bootstrapped/releases/download/prebuilts-extras-{version}/toolchain-extra-prebuilts-{version}-{target}.tar.zst".format(
            target = target,
            version = TOOLCHAIN_EXTRAS_VERSION,
        )],
    )
    for (target, sha256) in TOOLCHAIN_EXTRAS_SHA256.items()
]

tar_toolchains = use_extension("@tar.bzl//tar:extensions.bzl", "toolchains")
use_repo(
    tar_toolchains,
    "bsd_tar_toolchains_darwin_amd64",
    "bsd_tar_toolchains_darwin_arm64",
    "bsd_tar_toolchains_linux_amd64",
    "bsd_tar_toolchains_linux_arm64",
    "bsd_tar_toolchains_windows_amd64",
    "bsd_tar_toolchains_windows_arm64",
)

llvm_source = use_extension("//extensions:llvm_source.bzl", "llvm_source")
llvm_source.version(llvm_version = LLVM_VERSION)
use_repo(llvm_source, "compiler-rt", "libcxx", "libcxxabi", "libunwind", "llvm-libc", "llvm-raw", "llvm_config", "llvm_zlib", "llvm_zstd", "openmp")

llvm = use_extension("//extensions:llvm.bzl", "llvm")
llvm.configure(
    targets = [
        "AArch64",
        "X86",
        "WebAssembly",
        "NVPTX",
    ],
)
use_repo(llvm, "llvm-project")

musl = use_extension("//runtimes/musl/extension:musl.bzl", "musl")
use_repo(musl, "musl_libc")

mingw = use_extension("//runtimes/mingw/extension:mingw.bzl", "mingw")
use_repo(mingw, "mingw")

osx = use_extension("//extensions:osx.bzl", "osx")
osx.from_archive(
    sha256 = "6a4922f89487a96d7054ec6ca5065bfddd9f1d017c74d82f1d79cecf7feb8228",
    strip_prefix = "Payload/Library/Developer/CommandLineTools/SDKs/MacOSX26.2.sdk",
    type = "pkg",
    urls = ["https://swcdn.apple.com/content/downloads/26/44/047-81934-A_28TPKM5SD1/ps6pk6dk4x02vgfa5qsctq6tgf23t5f0w2/CLTools_macOSNMOS_SDK.pkg"],
)
use_repo(osx, "macos_sdk")

glibc = use_extension("//runtimes/glibc/extension:glibc.bzl", "glibc")

# https://cerisier.github.io/glibc-headers/index.json
glibc.index(file = "//runtimes/glibc/extension:glibc_headers_index.json")
use_repo(glibc, "glibc")

kernel_headers = use_extension("//kernel/extension:kernel_headers.bzl", "kernel_headers")

# https://cerisier.github.io/kernel-headers/index.json
kernel_headers.index(file = "//kernel/extension:kernel_headers_index.json")
use_repo(kernel_headers, "kernel_headers")

######################### DEV DEPENDENCIES ###################################

bazel_dep(name = "gazelle", version = "0.47.0", dev_dependency = True)
bazel_dep(name = "bazel_skylib_gazelle_plugin", version = "1.9.0", dev_dependency = True)
bazel_dep(name = "buildifier_prebuilt", version = "8.2.1", dev_dependency = True)
bazel_dep(name = "bazelrc-preset.bzl", version = "1.6.0", dev_dependency = True)

GLIBC_STUBS_GENERATOR_COMMIT = "33276300351d5a3cbedd308f4d21669b8e8ef83d"

bazel_dep(name = "glibc-stubs-generator", version = "2.0.1", dev_dependency = True)
archive_override(
    module_name = "glibc-stubs-generator",
    integrity = "sha256-q7bwGW3nRigiGuXj/2kIZMi/LFCHZpVbMD/kRdllLCg=",
    strip_prefix = "glibc-stubs-generator-{}".format(GLIBC_STUBS_GENERATOR_COMMIT),
    urls = ["https://github.com/cerisier/glibc-stubs-generator/archive/{}.tar.gz".format(GLIBC_STUBS_GENERATOR_COMMIT)],
)

LIBSTDCXX_STUBS_GENERATOR_COMMIT = "ed896a140ef8466140c3bcfd066e710a80a41ebe"

bazel_dep(name = "libstdcxx-stubs-generator", version = "0.0.1", dev_dependency = True)
archive_override(
    module_name = "libstdcxx-stubs-generator",
    integrity = "sha256-OAZfeifniTQmKit60qHpZanOLLIJVyYEiMlpN5Q7Fjw=",
    strip_prefix = "libstdcxx-stubs-generator-{}".format(LIBSTDCXX_STUBS_GENERATOR_COMMIT),
    urls = ["https://github.com/cerisier/libstdcxx-stubs-generator/archive/{}.tar.gz".format(LIBSTDCXX_STUBS_GENERATOR_COMMIT)],
)

PKGUTIL_COMMIT = "2fdc9a2d34d62332aa18e0c735afc8a7e7270530"  # v1.2.0

bazel_dep(name = "xpkgutil", version = "1.2.0", dev_dependency = True)
archive_override(
    module_name = "xpkgutil",
    integrity = "sha256-XHk51jB2RHDmeUI6JiYBAd5hqfI4kN+wpjTqE17WTqA=",
    strip_prefix = "pkgutil-{}".format(PKGUTIL_COMMIT),
    urls = ["https://github.com/cerisier/pkgutil/archive/{}.tar.gz".format(PKGUTIL_COMMIT)],
)

# pbzx support for libarchive
bazel_dep(name = "libarchive", version = "3.8.1.bcr.2", dev_dependency = True)
single_version_override(
    module_name = "libarchive",
    patch_strip = 1,
    patches = [
        "//3rd_party/libarchive:0001-libarchive_enable_xar_support.patch",
        "//3rd_party/libarchive:0002-feat-add-pbzx-read-filter.patch",
        "//3rd_party/libarchive:0003-give-mingw-acceptable-posix-types.patch",
    ],
)

# Workaround for their terrible toolchains...
bazel_dep(name = "rules_swift", version = "3.4.2", dev_dependency = True)
single_version_override(
    module_name = "rules_swift",
    patch_strip = 1,
    patches = ["//3rd_party/rules_swift:0001-allow-disabling-autoconfiguration.patch"],
    version = "3.4.2",
)

## OVERRIDES PORTS FROM DEPENDENCIES

bazel_dep(name = "rules_zig", version = "0.12.2", dev_dependency = True)

zig = use_extension("@rules_zig//zig:extensions.bzl", "zig", dev_dependency = True)
zig.index(file = "//:zig_index.json")
zig.toolchain(zig_version = "0.14.0")
zig.mirrors(urls = [
    "https://mirror.zml.ai/zig",
])
use_repo(zig, "zig_toolchains")

register_toolchains(
    "@rules_zig//zig/target:all",
    dev_dependency = True,
)

register_toolchains(
    "@zig_toolchains//:all",
    dev_dependency = True,
)