load("@rules_cc//cc:cc_test.bzl", "cc_test")
load("//:component_flags.bzl", "BUILD_VARIANTS", "variant_prefix")

_FFMPEG_TEST_COPTS = [
    "-D_ISOC11_SOURCE",
    "-D_FILE_OFFSET_BITS=64",
    "-D_LARGEFILE_SOURCE",
    "-std=c17",
    "-Wno-error=implicit-function-declaration",
] + select({
    "@platforms//os:macos": ["-D_DARWIN_C_SOURCE"],
    "//conditions:default": [],
})

# Public-API tests — representative of external consumption.
[
    cc_test(
        name = variant_prefix(v) + src + "_test",
        srcs = [src + ".c"],
        copts = _FFMPEG_TEST_COPTS,
        deps = [
            "//:{}avutil".format(variant_prefix(v)),
        ],
    )
    for v in BUILD_VARIANTS
    for src in [
        "avstring",
        "blowfish",
        "camellia",
        "cast5",
        "crc",
        "fifo",
        "hash",
        "md5",
        "murmur3",
        "ripemd",
        "sha",
        "sha512",
        "tea",
        "twofish",
        "uuid",
        "xtea",
    ]
]

# Internal tests — exercise internals via private headers.
[
    cc_test(
        name = variant_prefix(v) + src + "_test",
        srcs = [src + ".c"],
        copts = ["-DHAVE_AV_CONFIG_H"] + _FFMPEG_TEST_COPTS,
        deps = [
            "//:avutil_test_hdrs",
            "//:{}avutil".format(variant_prefix(v)),
        ],
    )
    for v in BUILD_VARIANTS
    for src in [
        "adler32",
        "base64",
        "integer",
    ]
]